GPS traces

Changer l'aspect de la carte

Cette carte est fournie avec un fichier TYP proposé par défaut par le site http://freizeitkarte-osm.de ; je vous propose un fichier TYP personnel que j'utilise depuis de nombreuses années et visible dans l'onglet Rendu dans Basecamp de cette même page ; pour le télécharger : cliquer ici.
GmapTool est un utilitaire fonctionnant sous Windows (avec une interface graphique sous Windows uniquement), Linux et OS X et qui permet entre autres de modifier le fichier TYP dans la carte gmapsupp.img du GPS.
Le site http://freizeitkarte-osm.de propose un utilitaire basé sur GmapTool pour Windows (avec un glisser-déposer) et Linux (en ligne de commande).
La marche à suivre pour remplacer le fichier TYP directement dans le GPS est la suivante :
1. Télécharger et installer le fichier ReplaceTyp.zip, le décompresser et ouvrir le répertoire qui vient d'être créé ;
2. connecter le GPS à votre ordinateur ;
3. sous Windows, ouvrir une deuxième fenêtre pour explorer le contenu du GPS (pour le Gmap 66s, cette fenêtre s'ouvre automatiquement au branchement du câble sur le GPS ; pour d'autres GPS, il faut l'ouvrir après avoir branché le câble depuis les paramètres : pour le 60Csx → Réglages>Interface) ;
4. faire glisser le fichier gmapsupp.img vers la première fenêtre sur le fichier ReplaceTyp.cmd ;
5. dans la console qui s'ouvre, sélectionnez la lettre du fichier TYP de votre choix dans la liste qui apparaît : le fichier TYP est aussitôt mis à jour dans le GPS ;
6. Pour ajouter un fichier TYP personnel dans la liste
   Lire la suite

   Ajouter ce fichier dans le répertoire d'installation de ReplaceTyp et éditer le fichier ReplaceTyp.cmd, avec un éditeur de texte simple (Bloc Notes, Notepad+, usine à gaz, MSWord, Open Office), en faisant un clic droit sur le fichier puis modifier... et non pas en le cliquant, puis incrémenter la liste avec le nom du nouveau fichier TYP ainsi qu'avec la lettre repère puis de reprendre les deux étapes ci-dessus.
   Voici dans l'exemple ci-dessous ce qui doit être modifié, indiqué en rouge, dans le fichier ReplaceTyp.cmd pour ajouter dans la liste de choix les fichiers gps.typ et gpstraces-net.typ, fichiers que l'on aura préalablement placés dans le même répertoire que ReplaceTyp.cmd :

   @echo off
   setlocal enabledelayedexpansion
   if "%~1"=="" goto error
   :: check the existence of gmaptool
   if not exist %~dps0gmt.exe goto error
   :again
   echo Select the desired TYP file:
   :: replace these with your own (and add as many as you want)
   echo A: freizeit - standard design of all Freizeitkarten project maps
   echo B: outdoor - design based on "Top50" and "ICAO" maps
   echo C: outdoor-light - no symbols on the areas included
   echo D: contrast - colors are "stronger" in compare to "freizeit"
   echo E: small - optimized for GPS devices with small displays
   echo F: outdoor-contrast - similar to contrast, no symbols in areas
   echo G: gps.typ - proposé par GPStraces.net
   echo H: gpstraces-net.typ - proposé par GPStraces.net
   echo Q: Quit
   echo.
   :: edit this too to match the number of options
   set /p userinp=Enter your choice (A-H, Q):
   set userinp=%userinp:~0,1%
   :: match the options above; use the typ file names here
   if /i "%userinp%"=="A" set typfile=freizeit.TYP
   if /i "%userinp%"=="B" set typfile=outdoor.TYP
   if /i "%userinp%"=="C" set typfile=outdoorl.TYP
   if /i "%userinp%"=="D" set typfile=contrast.TYP
   if /i "%userinp%"=="E" set typfile=small.TYP
   if /i "%userinp%"=="F" set typfile=outdoorc.TYP
   if /i "%userinp%"=="G" set typfile=gps.typ
   if /i "%userinp%"=="H" set typfile=gpstraces-net.typ
   if /i "%userinp%"=="Q" goto end
   if "%typfile%"=="" goto again
   :: check the existence of the chosen typ file
   if not exist %~dps0%typfile% goto error
   :: find FID of map in IMG file
   for /f "tokens=5 delims=, " %%G in ('%~dps0gmt.exe -i "%~1"^|findstr /c:", FID "') do set mapfid=%%G
   echo.
   echo.
   echo Family ID of this map: %mapfid%
   echo.
   echo.
   :: change FID of TYP file
   %~dps0gmt.exe -w -y %mapfid% %~dps0%typfile%
   :: add TYP file to IMG file
   %~dps0gmt.exe -w -x %~dps0%typfile% "%~1"
   echo.
   echo.
   echo .typ file in %~n1%~x1 is replaced by %typfile%
   goto end
   :error
   echo.
   echo.
   echo Prerequisite:
   echo.
   echo Keep the files ReplaceTyp.cmd, gmt.exe and the .typ files
   echo together in the same folder.
   echo.
   echo Usage:
   echo.
   echo Drag the gmapsupp.img file to the icon of ReplaceTyp.cmd
   echo and select the .typ file you want to use.
   :end
   echo.
   echo.
   pause

7. sous Linux, ouvrir une console dans le répertoire de ReplaceTyp et saisir dans cette console
   ReplaceTyp.sh /chemin_vers_mon_GPS/gmapsupp.img et choisir le fichier.TYP
   ou encore saisir directement
   ReplaceTyp.sh /chemin_vers_mon_GPS/gmapsupp.img myTypfile.TYP en ayant préalablement copié le fichier TYP dans le répertoire de ReplaceTyp ;
8. sous OS X, il y a une version expérimentale de GmapTool en ligne de commande ;
9. pour télécharger le fichier TYP utilisé dans l'onglet Rendu dans Basecamp de cette même page : cliquer ici ;
10. pour créer ou modifier un fichier TYP, l'incontournable TYPViewer, mais cela demande un peu de connaissances sur la structure des cartes vectorielles Garmin si l'on souhaite modifier autre chose que les couleurs.